Вспомогательные инструкции в коде 1С

Программирование - Практика программирования

контекстная подсказка Сервер и Не Сервер

49
Помогаем редактору кода 1С помогать нам писать и анализировать код.

Во встроенном языке 1С используется динамическая типизация переменных, т.е. при объявлении переменной в коде невозможно указать для нее допустимые типы значений. Тип значения переменной гарантированно становится известен только во время выполнения присвоения ей значения. Это придает языку простоту освоения, лаконичность, легкость и гибкость, но приносит с собой и сложности. К ним в частности относится вычисление типа значения выражения в режиме разработки (design-time), без чего не будут работать многие важные помощники при написании и анализе кода

Помощники опирающиеся на вычисление типа

1 Контекстная подсказка (автодополнение) (Ctrl+Space)

2 Подсказка по параметрам метода (Ctrl+Shift+Space)

3 Переход к определению (F12)

Принцип работы вычислителя типов режима разработки

  1. Определяется текущее выражение в тексте модуля
  2. Выделяются все переменные и функции, от которых оно зависит
  3. Для каждой переменной выполняется поиск выше по тексту присвоения ей выражения
  4. Для каждой функции выполняется анализ типа возвращаемого ею значения. В конфигураторе 1С это к большому сожалению не реализовано, но реализовано в EDT.
  5. Для каждого присвоения повторяются шаги 2-4

На платформе 1С 7.7 штатного вычислителя типов в режиме разработки не было. Но благодаря Орефкову Александру появилось стороннее API конфигуратора OpenConf. На базе него было сделано расширение с вычислением типов Телепат, которое стало прорывом в удобстве редактирования кода.

На платформе 1С 8.0 в конфигураторе появился свой вычислитель типов, но с заметно более скудными возможностями, чем Телепат 7.7 . Он НЕ умеет вычислять тип результата прикладной функции, колонки таблицы/дерева значений и многое другое, что умел Телепат 7.7. Позже появился сторонний API конфигутора Снегопат от того же Орефкова Александра. Но на его базе насколько мне известно так и не появилось расширения для продвинутого вычисления типа.

Привыкая к помощникам, опирающимся на вычислитель типов, начинаешь испытывать дискомфорт в случаях, где вычислителю не удается определить типы. Например при вызове автодополнения на иллюстрации

мы не увидим ожидаемого списка реквизитов строки табличной части Параметры справочника ирАлгоритмы. Хотя мы точно знаем, что в качестве параметра Алгоритм будет приходить всегда значение типа СправочникСсылка.ирАлгоритмы, вычислителю конфигуратора это не удастся понять.

Но можно заставить вычислитель режима разработки думать, что переменная имеет нужный тип, написав не исполняемый код присвоения этой переменной выражения с легко вычисляемым нужным типом.

Способ №1

Лучшим способом для конфигуратора 1С 8 является вставка всегда удаляемой инструкции препроцессора. Такой код всегда не будет компилироваться и потому не будет влиять на скорость компиляции и исполнения кода.

#Если Сервер И Не Сервер Тогда
    <Здесь пишем присвоение переменной выражения с нужным типом>
#КонецЕсли

Пример 1. Нужно указать переменной Алгоритм тип СправочникСсылка.ирАлгоритмы

    #Если Сервер И Не Сервер Тогда
        Алгоритм = Справочники.ирАлгоритмы.ПустаяСсылка();
    #КонецЕсли

Теперь будет работать контекстная подсказка у выражения, зависящего только от этой переменной:

Пример 2. Нужно указать переменной Отбор тип ОтборКомпоновкиДанных

    #Если Сервер И Не Сервер Тогда
        _ = Новый НастройкиКомпоновкиДанных;
        Отбор = _.Отбор;
    #КонецЕсли

Способ №2

Другим способом для конфигуратора 1С 8 является вставка всегда не исполняемого кода через всегда ложное условие. Такой код будет компилироваться. Исполняться (вычисляться) будет только выражение условия "Ложь", но не код внутри ветки Тогда. Здесь хотя и очень незначительное, но есть влияние на скорость компиляции и исполнения кода.

Если Ложь Тогда
    <Здесь пишем присвоение переменной выражения с нужным типом>
КонецЕсли;

Пример 1. Нужно указать переменной Алгоритм тип СправочникСсылка.ирАлгоритмы

    Если Ложь Тогда
        Алгоритм = Справочники.ирАлгоритмы.ПустаяСсылка();
    КонецЕсли;

Шаблоны текста для вспомогательных инструкций

Чтобы не набирать каждый раз вручную эти длинные конструкции, разумно добавить себе шаблон текста

Шаблон для способа 1

   #Если Сервер И Не Сервер Тогда
        <?>
    #КонецЕсли

Шаблон для способа 2

    Если Ложь Тогда
        <?>
    КонецЕсли;

Ссылки на методы

Иногда в коде приходится использовать ссылки на методы, т.е. не вызывать метод сразу, а передавать ссылку на него куда то, где его уже будут вызывать. На момент написания статьи в объектной модели 1С ссылки на методы поддерживаются в

  1. ФоновыеЗадания.Выполнить(<ПолноеИмяМетода>,...)
  2. Новый ОписаниеОповещения(<ИмяМетода>, <Модуль>,...)
  3. <ОбъектИнтерфейсаПользователя>.УстановитьДействие(..., <ИмяМетода>)
  4. КомандаФормы.Действие
  5. КнопкаКоманднойПанели.Действие
  6. ПодключитьОбработчикОжидания(<ИмяМетода>,...)
  7. ДобавитьОбработчик ..., <ОбработчикСобытия>;
В таких случаях в конфигураторе 1С не сработает командой "Перейти к определению" и потому переходить к определению метода приходится вручную. Тут тоже помогут вспомогательные инструкции. В них нужно указать вызов нужного метода и в любой момент можно будет переходить к нему командой "Перейти к определению".
 

Недостатки

  1. Из-за того, что эти вспомогательные инструкции не относятся к полезной логике программы, они затрудняют чтение кода и даже могут привести читателя кода в замешательство, если он не знаком с этим приемом.
  2. При переходе к определению переменной (F12) редактор будет активизировать нашу вспомогательную строку для присвоения типа. Нужно будет еще раз выполнить команду перехода (F12), чтобы перейти к настоящему определению.

Про EDT

На горизонте 1С появился EDT (Enterprise development tools) - новая среда разработки, которая по задумке должна стать лучше конфигуратора во всем, кроме задач администрирования. Там в частности реализован более умный чем в конфигураторе 1С 8 вычислитель, который должен превзойти Телепат 7.7. К сожалению описанные выше способы не будут работать с поумневшим вычислителем типов EDT. Он сразу понимает, что этот код не будет выполняться и потому не учитывает такой код при вычислении типов. Зато в EDT предусмотрена возможность гибко описывать типы параметров и возвращаемых значений методов для вычислителя типов. Выглядит это примерно так

Я пытался донести до разработчиков EDT потребность указывать типы в любом месте кода, но пока не был услышан.

Другие статьи по этой теме

49

См. также

Комментарии
Избранное Подписка Сортировка: Древо
1. Cyberhawk 108 15.10.18 12:15 Сейчас в теме
Такой код всегда не будет компилироваться
"Такой код никогда не будет компилироваться" звучит лучше
kote; CyberCerber; eeeio; +3 Ответить
2. tormozit 4906 15.10.18 12:16 Сейчас в теме
(1) Двойное отрицание нужно искоренять в нашем родном русском языке.
PVG_73; Ziggurat; IgorS; Ditron; +4 8 Ответить
3. TODD22 17 15.10.18 12:19 Сейчас в теме
(2)
Такой код всегда не будет компилироваться

Тогда можно убрать слово "всегда".
TreeDogNight; kote; CyberCerber; eeeio; +4 Ответить
5. tormozit 4906 15.10.18 13:07 Сейчас в теме
(3) Да можно, но для ясности хотелось подчеркнуть.
31. Steelvan 15.10.18 19:02 Сейчас в теме
(2) Это правильно.

В тему.
Я регулярно на вопросы, типа "Вам пакет не нужен ?" отвечаю "Да", если не нужен :)
yuran2000; +1 1 Ответить
33. tormozit 4906 15.10.18 23:16 Сейчас в теме
(31) Да, вопросы с отрицанием перед глаголом тоже в этом плане раздражают. Для однозначного восприятия ответа они требуют включения глагола в ответ. А ведь задающему вопрос часто всего то нужно убрать частицу "не" перед глаголом, чтобы отвечающий мог использовать варианты "да/нет".
60. kuzyara 527 17.10.18 07:58 Сейчас в теме
38. Armando 1387 15.10.18 23:57 Сейчас в теме
(31) Чтобы было легче отвечать на такие вопросы, я вопросительное предложение воспринимаю как утверждение: "Вам пакет не нужен". Если утверждение верно говорю Да, иначе Нет.
47. Kutuzov 442 16.10.18 09:39 Сейчас в теме
(31) Я против того, чтобы изделия Бостон Механикс комментили на Инфостарте ;)
48. Steelvan 16.10.18 09:49 Сейчас в теме
(47) Когда Ваш опыт серьезного программирования перевалит за 10+ лет, тогда вы вспомните эту переписку :)
50. Cyberhawk 108 16.10.18 10:33 Сейчас в теме
(2)
1. Что в нем плохого (в общем случае)?
2. Разве для тебя не очевидно, что в текущем конкретном случае от него явно больше пользы, чем от его отсутствия?
51. tormozit 4906 16.10.18 10:53 Сейчас в теме
(50)
1. Что в нем плохого (в общем случае)?

Противоречит логике.
52. Cyberhawk 108 16.10.18 11:00 Сейчас в теме
56. Cyberhawk 108 16.10.18 12:08 Сейчас в теме
(54) Слов там всяких слишком уж много.
По-твоему использование сочетания "никогда не" допускать никогда нельзя?
57. ADirks 180 16.10.18 14:29 Сейчас в теме
(54) что характерно, в 7.7 практически всё это сделано, кроме составных типов :))

типизация для интеллисенса обозначается специального вида коммментариями
Процедура тпЖурналПриВыводеСтроки(Источник, ОформлениеСтроки, ДанныеСтроки, ТипРегиона) Экспорт
//ОформлениеСтроки//:ОформлениеСтроки
Перем Яч;//:ОформлениеЯчейки

что мешает запилить это всё в восьмёрке для меня загадка
62. Ndochp 101 17.10.18 10:31 Сейчас в теме
(57)Нет интелисенса в 7.7. Точнее он такой же левый, как снегопат, турбоконф и тд и тп.
1С (фирма) не умеет в типизацию, так как не видит в ней необходимости.
64. ADirks 180 17.10.18 11:19 Сейчас в теме
(62) Это в восьмёрке нифига толком нет, а у меня всё есть. А если чего-то не хватает, то я могу сам это сделать (и собственно много чего сделал).
Если бы фирма 1С сделала конфигуратор с открытым интерфейсом (как OpenConf например), то и в восьмёрке бы давно всё было.
68. kaa_ 17.10.18 19:42 Сейчас в теме
(64) Вот они EDT и пилят. Популяризут, рассказывают о расширениях..
4. Восьмой 41 15.10.18 12:26 Сейчас в теме
Блин Америку открыли - смысл статьи то в чем?
До стучаться до разрабов EDT?
6. tormozit 4906 15.10.18 13:10 Сейчас в теме
(4) Кажется что в статье нет претензий на "открытие Америки". Главная ее цель - объяснить смысл таких странных фрагментов в коде тем, кто еще не познакомился с этим приемом. Как выяснилось, не все сразу понимают их смысл и потому некоторые приходят в замешательство при виде такого кода.
7. Восьмой 41 15.10.18 13:19 Сейчас в теме
(6)
Я еще в 2013 видел подобную статью на одном из форумов. И да - это прием исключительно для процесса разработки, разработчик который выкладывает подобное в релиз да еще и без комментариев - поступает весьма не вежливо.
8. tormozit 4906 15.10.18 13:25 Сейчас в теме
(7) Какие комментарии для такого вспомогательного кода тебе кажутся вежливыми?
10. Восьмой 41 15.10.18 14:33 Сейчас в теме
(8) Коллега вы ради этого статью целую написали, чтобы донести в массы свою мысль. Так же ведь и с комментариями.
11. tormozit 4906 15.10.18 14:43 Сейчас в теме
(10) Ожидал ответа по существу, а получил ответ-ссылку. Все таки раз уж ты высказался по поводу отсутствия комментариев, то было бы вежливо пояснить, какие именно комментарии тебе кажутся подходящими.
AntonSm; kote; +2 2 Ответить
9. ADirks 180 15.10.18 14:25 Сейчас в теме
(7) Почему невежливо то? Мне, как разработчику, наоборот приятно, что кто-то озаботился о моём комфорте.
На работе системы же это никак не скажется.
18. Rustig 1021 15.10.18 17:17 Сейчас в теме
(4) прочитайте внимательно :)
12. t.v.s. 86 15.10.18 14:54 Сейчас в теме
Идея хорошая, спасибо за наводку.
Предлагаю расширить вот так:
#Область DesignerHelper
    //Содержимое этой области не несет полезной нагрузки и необходимо исключительно для облегчения процесса разработки
    #Если Сервер И Не Сервер Тогда
        Алгоритм = Справочники.ирАлгоритмы.ПустаяСсылка();
    #КонецЕсли
#КонецОбласти

Ну а в релизной версии скриптом эти области вырезать
kembrik; le0nid; gorakh; Восьмой; +4 Ответить
15. Darklight 15 15.10.18 15:30 Сейчас в теме
(12)Уже начинает попахивать бестолковым нагромождением. Вот, если бы эту идею дальше развивать - на парадигму контрактного программирования - и в такой области описывать более ёмкие контракты: описывающие все типы входных, выходных параметров (и возвращаемого результата), осуществляющих тестирование значений (либо всегда, либо только для режима отладки) да так, чтобы по ним ещё и можно было генерировать как комментарий к функции (учитываемый, кстати, IDE в контекстной подсказке, когда задан в соответствующем формате), так и для автосоздания документации к программному коду.


Функция МояФункция(Праметр1, Параметр2)
#Область Контракт
    //Содержимое этой области не несет полезной нагрузки и необходимо исключительно для облегчения процесса разработки
    Результат = Новый СписокЗначений(); 
    #Если Сервер И Не Сервер Тогда
        Параметр1= Справочники.ирАлгоритмы.ПустаяСсылка();
        Параметр2= Справочники.Номенклатура.ПустаяСсылка();
        Параметр2= Справочники.НоменклатурнаяГруппа.ПустаяСсылка();
    #КонецЕсли
    Если омОтладка.ЭтоОтладка() Тогда
        Если ТипЗнч(Праметр1) <> Тип("СправочникСсылка.ирАлгоритмы") или  Праметр1.ПустаяСсылка() Тогда
            вызватьисключение "Параметр1 может быть только не пустым элементом типа ""СправочникСсылка.ирАлгоритмы"""
        КонецЕсли;
        Если (ТипЗнч(Праметр2) <> Тип("СправочникСсылка.Номенклатура") 
                  ТипЗнч(Праметр2) <> Тип("СправочникСсылка.НоменклатурнаяГруппа") )
          или  Праметр2.ПустаяСсылка() 
          или  Праметр2.ЭтоГруппа() 
       Тогда
            вызватьисключение "Параметр1 может быть только не пустым элементом типов ""СправочникСсылка.Номенклатура"", ""СправочникСсылка.НоменклатурнаяГруппа"" "
        КонецЕсли;
    КонецЕсли;
#КонецОбласти //Контракт

//какой-то код, заполняющий результат элементами справочника номенклатура

#Область Контракт

#КонецОбласти //Контракт
    Если омОтладка.ЭтоОтладка() Тогда
        Если ТипЗнч(Результат) <> "СписокЗначений" или не отОтладка.СодержитТолькоТип(Результат,"СправочникСсылка.Номенклатура") Тогда
            вызватьисключение "Результат не типа ""СписокЗначения"" или содержит элементы не типа ","СправочникСсылка.Номенклатура""";
    КонецЕсли;
КонецФункции //МояФункция

Показать


А ещё в такие контакты можно встраивать алгоритмы unit-тестирования, спящие пока не придёт время.

Но это всё будет дико смотреться в коробочной версии - в ней такой код лучше всего вычищать обработкой выгруженных в файлы текстов и генерить на его основе комментарий к функции и автодокументацию. А такую конфигурацию оставлять для анализа и отладки - только тем, клиентам коробочного решения , кому захочется в ней копаться.
Восьмой; +1 Ответить
63. Ndochp 101 17.10.18 10:32 Сейчас в теме
(12)Ну и злая ты буратина. А о внедренцах ты не думаешь, или специально им гадости делаешь?
65. t.v.s. 86 17.10.18 11:30 Сейчас в теме
(63) Крайне занятная предъява. В чем гадость моего предложения?
66. Ndochp 101 17.10.18 14:54 Сейчас в теме
(65)Ну ты когда код писал жил с подсказкой реквизитов через точку. А когда придет после тебя другой человек базу дорабатывать, у него уже эта функция работать не будет, так как ты специально грохнул все удобства.
13. Darklight 15 15.10.18 15:06 Сейчас в теме
Забавно, возьму на заметку. А так, конечно, буду ждать встроенных в платформу инструкций по "типизации" переменных и ещё более продвинутое выведение типов - как в современных строго и не строго типизированных языках программирования. Боюсь только ждать долго придётся... язык 1С и так уже отсатёт на 10-20 лет от современных тенденций в разработке программ, и, даже не пытается за ними следовать - с каждым десятилетием отставая всё больше и больше.

Такое впечатление, что компания 1С "болт забила" на развитие языка. Ну, ей сейчас не до этого, ей нужно EDT "до ума разума" доводить. Мне кажется в следующем поколении 1С Предприятия (9-том) компания 1С вообще откажется от своего собственно языка и перейдёт на более популярный не то что в мире, даже в России - Java (ну или Java Script если надо будет оставить динамическую типизацию). Любовь к платформе Java компания не первый год питает. Вероятно и 1С: Предприятие 9 в большей своей части будет написана уже под Java runtime, с применением LLVM. Да и в попытке продвигать 1C Enterprise на запад - тоже полезно было бы не пытаться навязать им бейсикоподобную рухлять - а презентовать то, к чему пол мира уже привыкло - полноценный или почти полноценный Java-cинтаксис, хотя бы уровня 8-й генерации. Может и продвижение среды сразу более эффективно пойдёт на запад.
14. m.bolsun 625 15.10.18 15:25 Сейчас в теме
В TurboConf этот процесс можно автоматизировать. Программа сама создаст специальную секцию и будет в нее добавлять такие объявления типов.

Восьмой; Darklight; +2 Ответить
16. Восьмой 41 15.10.18 16:57 Сейчас в теме
Между прочим можно вот так:

 	
#Если КонтрактныйИнтерфейс тогда
		Документ = Новый ТаблицаЗначений;
	#КонецЕсли
 



Прекрасно работает.
19. tormozit 4906 15.10.18 17:36 Сейчас в теме
(16) Можно, но опасно. В будущем неизвестные идентификаторы могут объявить некорректными. Я лично просил разработчиков платформы так сделать, чтобы защитить от опечаток. Например Истина и Ложь уже являются таковыми. Остальные пока все еще разрешены и трактуются как Ложь.
49. Darklight 15 16.10.18 10:06 Сейчас в теме
(19)Надо не просто запрещать - а дать возможность самим вводить такие термины. Как это можно было делать в Си (привет #define ну и #undef тоже хотя эта директива уже не так важна). Эх, так хочется иметь опции, которыми можно было бы управлять составом конфигурации при компиляции, в зависимости от использования в той или иной версии конфигурации/платформы или просто включать/выключать тот или иной используемый/неиспользуемый в данной ИБ функционал, в т.ч. отладочный.
17. Rustig 1021 15.10.18 17:16 Сейчас в теме
(0) профессионально описано!
20. Dzenn 260 15.10.18 17:38 Сейчас в теме
Я использую следующий способ:


Спр = Справочники.Номенклатура.НайтиПоКоду("").ПолучитьОбъект(); ВызватьИсключение "Отладка"; 

21. tormozit 4906 15.10.18 17:43 Сейчас в теме
(20) Способ для чего? Хорошо бы немного прокомментировать свой способ.
22. Dzenn 260 15.10.18 17:44 Сейчас в теме
(21) для явного указания типа, когда 1С не может его определить
24. tormozit 4906 15.10.18 17:55 Сейчас в теме
Ну если уж захотел поделиться опытом, то и пояснил бы сразу что добавка
ВызватьИсключение "Отладка";
защитит при случайной потере экранирующих конструкций. Ведь не все догадаются об этом.
Но дописывать эту добавку в каждой строке будет довольно расточительно. В моем большом опыте использования такого вспомогательного кода не было случаев, когда бы она сработала. Поэтому я не стану ее использовать и думаю также сделает большинство.
23. Восьмой 41 15.10.18 17:54 Сейчас в теме
(20) Жесть какая-то

(19) Эххххх если бы 1Совцы нас слушали...… я вот до сих пор мечтаю о что в конструктор запросов добавят поддержку комментариев.
25. Dzenn 260 15.10.18 17:56 Сейчас в теме
(23) почему "жесть"? Использую этот подход при отладке, потом такие строки убираю
27. Восьмой 41 15.10.18 18:19 Сейчас в теме
(25) Право ваше, просто я за 13 лет не могу вспомнить ни одного случая когда бы такое могло пригодится, для меня это - "больно уж умно только вот не понятно"
29. Dzenn 260 15.10.18 18:26 Сейчас в теме
(27) А что тут непонятного?

Пришла, например, переменная Спр в качестве параметра функции, и я знаю, что это "СправочникОбъект.Номенклатура", а 1С этого не знает. Я инициализирую переменную, не забывая в ту же строку вставить "ВызватьИсключение "Отладка"", и дальше пользуюсь контекстными подсказками — реквизиты через точку, функции модуля и прочее. А когда написал весь нужный мне код — удаляю отладочную инициализацию. А если забыл удалить — 1С сама мне об этом напомнит вызовом исключения, когда буду отлаживать. Ну и плюс, все отладочные конструкции видны по CTRL-F.
CSiER; Bassgood; Восьмой; +3 Ответить
30. Восьмой 41 15.10.18 18:35 Сейчас в теме
(29) Признаю свое невежество - прикольный способ, возьму на заметку.
34. tormozit 4906 15.10.18 23:24 Сейчас в теме
(29)
если забыл удалить — 1С сама мне об этом напомнит вызовом исключения
Это если код линейный, что бывает далеко не всегда. Если будет например оператор ветвления, то опасность оставить такой код вырастает ощутимо, а каждый раз делать поиск маркера в тексте - утомительно.
В общем предложенный тобой прием понятен, но он опаснее, чем описанные в статье. Ведь фрагменты из статьи можно и оставлять и удалять в любой момент и при этом логика программы не подвергается риску изменения.
35. Dzenn 260 15.10.18 23:27 Сейчас в теме
(34) я использую это в рамках одной процедуры/функции, а в рамках одной процедуры/функции нелинейного кода у меня не бывает в принципе
36. tormozit 4906 15.10.18 23:33 Сейчас в теме
(35) Т.е. ты не используешь условный оператор (оператор ветвления) в методах?
Функция ФУ(Фа)
	Если Фа = 1 Тогда
		Спр = Справочники.Номенклатура.НайтиПоКоду("").ПолучитьОбъект(); ВызватьИсключение "Отладка"; 
	ИначеЕсли Фа = 2 Тогда
		Спр = Справочники.Номенклатура.НайтиПоКоду("").ПолучитьОбъект(); ВызватьИсключение "Отладка"; 
	Иначе
		Спр = Справочники.Валюты.НайтиПоКоду("").ПолучитьОбъект(); ВызватьИсключение "Отладка"; 
	КонецЕсли; 
КонецФункции
Показать

Чтобы покрыть такой код сценарным тестом, пользователю нужно будет выполнить такие действия, чтобы сработала каждая ветвь условия.
37. Dzenn 260 15.10.18 23:45 Сейчас в теме
(36) использую, конечно, но стараюсь, чтобы процедуры/ функции были как пуля ;-) однозначными и линейными. Нелинейность и ветвления можно организовать в другой процедуре, в которой не будет нашей переменной
26. tormozit 4906 15.10.18 17:58 Сейчас в теме
(23) Поддержка комментариев кстати уже давно есть в конструкторе запроса ИР.
28. Восьмой 41 15.10.18 18:21 Сейчас в теме
(26) ИР штука хорошая и полезная, но хотелось бы в штатных конструкторах.
45. SerVer1C 153 16.10.18 09:03 Сейчас в теме
(23) Со времен 7.7 хочу простые операции: инкремент и декремент. Это же так просто. В "байт-коде" это же реализовано.
Dem1urg; the1; +2 Ответить
32. yurii_host 1853 15.10.18 20:04 Сейчас в теме
Автор, спасибо за статью.
Тоже давно использую Если Ложь, про способ прятать через директивы не знал.
Кроме самого приема интересно было почитать про EDT и вычислитель типов
39. kote 487 16.10.18 00:41 Сейчас в теме
Чего только люди не придумают - лишь не давать нормальные имена переменным и/или не рефакторить код.. ))
41. tormozit 4906 16.10.18 01:16 Сейчас в теме
(39) Причем тут имена переменных? Статью то прочитал? =)
43. kote 487 16.10.18 01:53 Сейчас в теме
(41) intellisens зло. Все должно быть просто и понятно без этих дьявольских штучек!
40. kote 487 16.10.18 00:43 Сейчас в теме
Хмм.. а разве директивы не поддерживают Истина/Ложь?
В конечном итоге - ЭтоСервер - это же тоже булева переменная, не?
42. tormozit 4906 16.10.18 01:19 Сейчас в теме
(40)
а разве директивы не поддерживают Истина/Ложь?
Если сомневаешься, лучший способ проверить верность утверждения - проверить его самому. Тем более проверить это можно очень легко и быстро.
В конечном итоге - ЭтоСервер - это же тоже булева переменная, не?
Не понял. Что такое ЭтоСервер? Можешь подробнее описать свою мысль?
44. kote 487 16.10.18 01:55 Сейчас в теме
(42)
Имел ввиду переменную Сервер в выражении
#Если Сервер Тогда..
46. SerVer1C 153 16.10.18 09:17 Сейчас в теме
Автор знает интересные особенности в 1с. Плюсую!
59. webester 28 17.10.18 04:07 Сейчас в теме
(46)Автор уважаем и широко известен в узких кругах своими шикарными проектами, конечно он что-то знает про 1С. Но приему 100 лет в обед, честное слово.
67. SerVer1C 153 17.10.18 15:48 Сейчас в теме
(59) Да, кэп. Но понятное вам не означает, что это понимает каждый из сообщества данного сайта.
70. webester 28 18.10.18 02:04 Сейчас в теме
(67) Я где-то утверждал обратное?
55. tsukanov 65 16.10.18 12:00 Сейчас в теме
Про EDT:

Более менее вменяемое указание типов разработчики могут сделать довольно легко.
Для этого нужно только добавить в синтаксис языка необязательные аннотации типов:
Функция Тест(Пар: Тип1)
    Перем Прм: Тип2
КонецФункции

Имена типов могут быть именами встроенных типов платформы, либо именами пользовательских типов.

Для определения пользовательских в языке и платформе ничего менять не надо.
Достаточно разрешить использовать имена пользовательских функций! )

Т.е., учитывая, что EDT умеет выводить типы, мы можем определять свои типы просто написав соответствующую функцию.
Например:
Функция ТипПользователь()
    Пользователь = Новый Структура;
    Пользователь.Вставить("Имя", "");
    Возврат Пользователь;
КонецФункции

EDT легко выведет тип этой функции. И гипотетически может использовать имя этой функции в качестве типа.
Т.е. мы могли бы написать:
Функция Тест(Пар: ТипПользователь)
    Перем Прм: Тип2
КонецФункции

и EDT мог бы отслеживать ошибки и давать подсказки исходя из известного ему типа.

Кроме того определение типов с помощью функций решает проблему определения сложных составных типов без какого либо изменения синтаксиса. Единственное изменение в языке - это необязательные аннотации (двоеточие + имя). Все остальное может сделать EDT

Такой вот концепт )
58. ADirks 180 16.10.18 14:36 Сейчас в теме
или вот такую штуку почему не сделают? (динамический фильтр по подстроке в списке свойств/методов)
прям очень не хватает
Прикрепленные файлы:
61. zqzq 17 17.10.18 09:00 Сейчас в теме
Я тоже уже много лет использую шаблон
#Если ДляСинтаксПодсказки Тогда
        <?>
#КонецЕсли

+ Работает
+ Более наглядно чем Сервер И Не Сервер, которое может сбивать с толку
- Может перестать работать в будующих версиях, как уже отмечали. Но тогда можно пройтись глобальным поиском и заменой, благо не типовую и не массовую конфу разрабатываю.
69. SlavaKron 17.10.18 20:25 Сейчас в теме
Удивительно, как столь неважная проблема нашла так много откликов. Видимо, я что-то не понимаю.
71. PerlAmutor 32 18.10.18 11:01 Сейчас в теме
Тоже думал как такое реализовать. Метод интересен. Жаль не избавляет от ошибки на этапе выполнения, когда тип переменной внезапно оказывается не тем типом, который ожидается получить. Но уж лучше чем лезть в справочник.

По теме полезностей в конфигураторе. Хочется аналог PVS Studio, CppCheck и Coverity Scan, для статического анализа кода конфигурации, с доп.функционалом по проверке орфографии в названиях переменных и именах объектов метаданных.
73. PerlAmutor 32 18.10.18 11:38 Сейчас в теме
74. tormozit 4906 18.10.18 12:41 Сейчас в теме
Указал в статье ссылку на тему партнерского форма, где я пытался в очередной раз объяснить разработчикам EDT потребность в подобных инструкциях. Помогайте, кто имеет доступ.
75. teploukhov 20.10.18 08:51 Сейчас в теме
Статьи автора - мои самые любимые статьи на сайте. Очень много приемов взял на вооружение именно благодаря Сергею. Но данная конкретная статья является жутким баяном-бабаяном.
https://infostart.ru/public/65470/
tormozit; +1 Ответить
76. tormozit 4906 20.10.18 09:16 Сейчас в теме
(75) Спасибо за ссылку. Я ее не нашел поиском. Добавил в статью раздел "Другие статьи по этой теме"
teploukhov; +1 Ответить
77. PerlAmutor 32 21.10.18 07:13 Сейчас в теме
(76) Вот так проходят десятилетия в 1С. Старые проблемы, старые решения...новые статьи.
78. tormozit 4906 21.10.18 13:04 Сейчас в теме
Похоже разработчики EDT все таки нас услышали на партнерском форуме и сообщили о планах предоставить универсальный способ указывать типы для design-time в любом месте кода.
79. tormozit 4906 27.10.18 16:42 Сейчас в теме
Добавил раздел "Ссылки на методы"
Оставьте свое сообщение